import ddf.minim.*;

import traer.physics.*;
import megamu.shapetween.*;

int reflectionHeight = 100;
float surface = 400;

AudioSample thump;

DigiSquare square;

ParticleSystem physics;
PImage table;
PImage reflection;

void setup(){
  size( 800, 600 );
  frameRate( 30 );
  colorMode( HSB, 1 );
  noStroke();
  smooth();
  
  Minim.start(this);
  thump = Minim.loadSample("BD.mp3", 512);
  
  physics = new ParticleSystem( 1, 0.1 );
  
  square = new DigiSquare();
  
  reflection = createImage( width, reflectionHeight, RGB );
  Shaper reflectShape = Shaper.getInstance( Shaper.QUAD_OUT );
  table = createImage( 1, height, ARGB );
  for( int i=0; i<height; i++ )
    table.pixels[i] = color( 0, 0.6 + 0.4*reflectShape.shape( min((float)i/reflectionHeight, 1)) );
}

void draw(){
  background( 0 );
  
  pushMatrix();
  
  square.draw();
  
  popMatrix();
  
  // product table effect
  loadPixels();
  for( int w=0; w<width; w++ )
    for( int h=0; h<reflectionHeight; h++ )
      reflection.pixels[ h*width + w ] = pixels[ ((int)surface - h)*width + w ];
  reflection.updatePixels();  
  image( reflection, 0, surface-1);
  image( table, 0, surface-1, width, height );  
}

void mousePressed(){
  if( mouseY <= surface && pixels[ mouseX + mouseY*width ] != color(0) )
    square.drag(true);
}

void mouseReleased(){
  square.drag(false);
}

void mouseMoved(){
  square.mouseMoved();
}

void stop(){
  thump.close();
  super.stop();
}