// square is a state machine.

class DigiSquare{
  
  final int FALLING = 0;
  final int SPAWN_RUB = 0;
  
  int state;
  boolean onSurface, wasOnSurface, canTriggerAgain;
  float energy;
  float cx, cy;
  float happy;
  
  float lastAngle;
  float vA;
  
  float eyeAngle;
  
  Particle[] corner;
  
  Particle m;
  Spring[] mS;
  
  DigiSquare(){
    state = FALLING;
    onSurface = false;
    wasOnSurface = false;
    canTriggerAgain = false;
    
    energy = 0;
    happy = 1;
    
    eyeAngle = 0;
    
    lastAngle = -1.5;
    vA = 0;
    
    m = physics.makeParticle( 1, 0, 0, 0 );
    m.makeFixed();
    
    mS = new Spring[4];
    corner = new Particle[4];
    
    int half = corner.length / 2;
    
    // create corners
    for( int i=0; i<corner.length; i++ ){
      float x = width/2 - 40;
      float y = -100;
      if( i<half ){
        x += ( i%2==1 ) ? 80: 0;
        y += 0;
      }else{
        x += ( i%2==1 ) ? 0 : 80;
        y += 80;
      }
      corner[i] = physics.makeParticle( 1, x, y, 0 );
    }
    
    // attach them
    for( int i=0; i<corner.length; i++ ){
      physics.makeSpring( corner[i], corner[(i+1)%corner.length], 1.5, 0.001, 80 );
      if( i < half )
        physics.makeSpring( corner[i], corner[(i+half)%corner.length], 1.5, 0.001, 113.14 );
      mS[i] = physics.makeSpring( corner[i], m, 0.4, 0.6, 0 );
    }
    drag( false );
  }
  
  void draw(){
    happy = 0.5;
    
    // physics
    wasOnSurface = onSurface;
    onSurface = false;
    m.moveTo( mouseX, mouseY, 0 );
    for( int i=0; i<corner.length; i++ ){
      float rx = random( energy*1.5 );
      rx *= rx * (random(1)>0.5?1:-1);
      float ry = random( energy*1.5 );
      ry *= ry * (random(1)>0.5?1:-1);
      corner[i].addVelocity( rx, ry, 0 );
    }
    physics.tick();
    
    // out of bounds
    boolean outOfBounds = false;
    for( int i=0; i<corner.length; i++ )
      if( corner[i].position().y() < -250 ){
        outOfBounds = true;
        break;
      }
    if( outOfBounds ){
      for( int i=0; i<corner.length; i++ )
        corner[i].moveBy( 0, surface*2, 0 );
    }
    
    for( int i=0; i<corner.length; i++ )
      bounceSurface( corner[i] );
    physics.setGravity( onSurface?0.01:2 );
    energy *= 0.995;
    
    // center
    cx = ( corner[0].position().x() + corner[2].position().x() ) / 2;
    cy = ( corner[0].position().y() + corner[2].position().y() ) / 2;

    // draw square
    noStroke();
    fill( 0.7 );
    beginShape();
    for( int i=0; i<corner.length; i++ )
      vertex( corner[i].position().x(), corner[i].position().y() );
    endShape();
    
    // draw rubbing spot
    float handle = 0.55;
    float spotSize = 0.4;
    fill( 0.6 + min(0.4, energy*0.1), 0.7, 0.7 );
    beginShape();
    for( int i=0; i<corner.length; i++ ){
      float px = cx + (corner[i].position().x()-cx)*spotSize;
      float py = cy + (corner[i].position().y()-cy)*spotSize;
      float tx = cx + (corner[(i+1)%corner.length].position().x() - cx)*spotSize;
      float ty = cy + (corner[(i+1)%corner.length].position().y() - cy)*spotSize;
      if( i==0 )
        vertex( px, py );
      bezierVertex( px + (tx-cx)*handle, py + (ty-cy)*handle,
                    tx + (px-cx)*handle, ty + (py-cy)*handle,
                    tx, ty );
    }
    endShape();
    
    // rotations
    float angle = fixAngle( atan2( corner[0].position().y()-cy, corner[0].position().x()-cx) );
    if( abs( fixAngle(angle - lastAngle)*5 ) > abs(vA) )
      vA = fixAngle(angle - lastAngle)*5;
    vA *= vA>0.1?0.99:0.6;
    lastAngle = angle;
    
    // doesn't like to spin
    happy -= vA*0.25;
    
    // doesn't like being upside down
    happy -= abs( fixAngle(angle + 2.356) )*0.2;
    
    // wants attention!
    float mouseDist = dist(cx,cy,mouseX,mouseY);
    happy += max(0, (200 - mouseDist)/600);
    
    // likes energy!
    happy += energy*0.25;
    
    happy = constrain( happy, 0, 1);
    
    // draw eye
    float watch = atan2( mouseY-cy, mouseX-cx);
    float dA = fixAngle( watch - eyeAngle );
    vA += constrain( dA*0.5, -0.1, 0.1 );
    eyeAngle += constrain( vA, -1, 1);
    eyeAngle = fixAngle(eyeAngle);
    
    
    float watchDist = min( 12, mouseDist*0.2 );    
    fill(0.02);
    pushMatrix();
    translate( cx, cy );
    rotate( eyeAngle );
    ellipse( watchDist, 0, 8, 8 );
    popMatrix();
    
    // draw mouth
    float mouthCorner = lerp( 0.20, 0.4, happy);
    float mouthSmile = lerp( -0.25, 0.55, happy );
    float mouthCurve = lerp( 0.4, 0.55, happy );
    float mouthLX = corner[3].position().x()*(1-mouthCorner) + cx*mouthCorner;
    float mouthLY = corner[3].position().y()*(1-mouthCorner) + cy*mouthCorner;
    float mouthRX = corner[2].position().x()*(1-mouthCorner) + cx*mouthCorner;
    float mouthRY = corner[2].position().y()*(1-mouthCorner) + cy*mouthCorner;
    float mouthCX = cx + (mouthLY - mouthRY)*mouthSmile;
    float mouthCY = cy + (mouthRX - mouthLX)*mouthSmile;
    
    strokeWeight( 1.5 );
    stroke(0.02);
    if( mouthSmile > 0 )
      fill(0.02);
    else
      noFill();

    bezier( mouthLX, mouthLY,
            mouthLX + (mouthCX-cx)*mouthCurve, mouthLY + (mouthCY-cy)*mouthCurve,
            mouthRX + (mouthCX-cx)*mouthCurve, mouthRY + (mouthCY-cy)*mouthCurve,
            mouthRX, mouthRY );
    
  }
  
  void bounceSurface( Particle p ){
    
    if( surface - cy > 60 )
      canTriggerAgain = true;
    
    if(p.position().y() > surface ){
      p.moveTo( p.position().x(), surface, 0 );
      p.setVelocity( 0, p.velocity().y()*0.5, 0);
      if( !onSurface && !wasOnSurface && canTriggerAgain ){
        thump.trigger();
        canTriggerAgain = false;
      }
      onSurface = true;
    }
      
    if(p.position().x() < 0){
      p.moveTo( 0, p.position().y(), 0 );
      p.addVelocity( p.velocity().x()*(-1.4), 0, 0 );
      thump.trigger();
    }else if(p.position().x() > width){
      p.moveTo( width, p.position().y(), 0 );
      p.addVelocity( p.velocity().x()*(-1.4), 0, 0 );
      thump.trigger();
    }
  }
  
  void drag( boolean on ){
    for( int i=0; i<mS.length; i++ )
      if( on ){
        mS[i].setRestLength( dist( mouseX, mouseY, mS[i].getOneEnd().position().x(), mS[i].getOneEnd().position().y() ) );
        mS[i].turnOn();
      }else{
        mS[i].turnOff();
      }
  }
  
  void mouseMoved(){
    if( dist( mouseX, mouseY, cx, cy ) < 60 && (mouseX != pmouseX || mouseY != pmouseY) ){
      float e = max(1, dist( mouseX, mouseY, pmouseX, pmouseY ));
      e = max(0, 3 - log(e));
      energy += (float) e*0.02;
      energy = constrain( energy, 0, 5 );
    }
    
  }
  
  float fixAngle( float in ){
    while( in > PI )
      in -= TWO_PI;
    while( in < -PI )
      in += TWO_PI;
    return in;
  }
  
}