/*
 * Artists - represents a collection of 'Artist'
 */
class Artists{

  static final boolean LOG = true;
  static final boolean LINEAR = false;

  int maxPlays;            // The maximum plays from any artist
  Vector artistList;       // A list of artist, sortable by many means
  HashMap artistMap;       // A lookup map of artist names to their respective objects
  ListeningHistory parent; // The history object that contains this
  boolean logPopularity; // should this be logarithmic or linear

  Artists(ListeningHistory parent){
    this.parent = parent;
    this.maxPlays = 0;

    artistList = new Vector();
    artistMap = new HashMap();
    
    logPopularity = true;
  }
  
  void setPopularityScale(boolean l){
    if(logPopularity != l){
      logPopularity = l;
      for(int i=0; i<artistList.size(); i++)
        ((Artist) artistList.get(i)).clearPopularityCache();
    }
  }
  
  boolean getPopularityScale(){
    return logPopularity;
  }

  int getMaxPlays(){
    return maxPlays;
  }

  int getCount(){
    return artistList.size();
  }

  Artist getArtist(int id){
    return (Artist) artistList.get(id);
  }

  Artist getArtist(String name){
    return (Artist) artistMap.get(name);
  }

  boolean containsArtist(String name){
    return artistMap.containsKey(name);
  }

  Artist addArtist(String name){
    if(this.containsArtist(name))
      return this.getArtist(name);
     
    int id = artistList.size();
    
    Artist a = new Artist(name, id, this);
    artistList.add(a);
    artistMap.put(name, a);

    return a;
  }

  void sortByPopularity(){
    Collections.sort(artistList, new SortByPopularity());
  }

  void sortByFirstPlay(){
    Collections.sort(artistList, new SortByFirstPlay());
  }

  class SortByPopularity implements Comparator{
    public int compare(Object o1, Object o2){
      return ( (Artist) o2).getTotalPlays() - ( (Artist) o1).getTotalPlays();
    }
  }

  class SortByFirstPlay implements Comparator{
    public int compare(Object o1, Object o2){
      return int( ( (Week) ( (Artist) o1).getFirstPlay()).getDate() - ( (Week) ( (Artist) o2).getFirstPlay()).getDate() );
    }
  }

}